10 CLS
20 PRINT "       SPEAKER CONE PATTERN DIMENSIONS CALCULATOR"
30 PRINT
40 PRINT "This program will calculate the size of a circle of paper"
50 PRINT "required to create a cone of a specified size.  In addition,"
60 PRINT "this program will also calculate the chord segment you must"
70 PRINT "draw, or indicate on your circle, such that you will know"
80 PRINT "precisely the dimensions of the 'pie' shaped section to cut"
90 PRINT "out of your circle to properly form it into a cone."
100 PRINT
110 PRINT "Key in the appropiate response for one of the following;"
120 PRINT
130 PRINT " 1 - Design a speaker cone"
140 PRINT "       - Giving required depth and width"
150 PRINT "       - adjacent sizes will also be displayed"
160 PRINT
170 PRINT " 2 - Display instructions"
180 PRINT
190 PRINT " 3 - Quit program"
200 PRINT
210 INPUT "Enter response (1, 2 or 3) here then press Enter ===> ",Q$
220   IF Q$="1" THEN GOTO 270
230   IF Q$="2" THEN GOTO 360
240   IF Q$="3" THEN SYSTEM
250 PRINT:PRINT "You did not enter a valid response.  Press Enter"
260 INPUT "now to make another selection",Q$:RUN
270 PRINT
280 PRINT "CONE DEPTH:"
290 INPUT "Enter required cone depth (To nearest 1/4 inch, ex. 8.25): ",H1
300   IF H1=0 OR H1/.25 <> INT(H1/.25) THEN                                              PRINT "Depth not multiple of 1/4 inch, re-enter":GOTO 290
310 PRINT
320 PRINT "CONE WIDTH:"
330 INPUT "Enter required cone width  (To nearest 1/4 inch, ex. 4.75): ",W1
340   IF W1=0 OR W1/.25 <> INT(W1/.25) THEN                                              PRINT "Width not multiple of 1/4 inch, re-enter":GOTO 330
350 GOTO 610
360 CLS
370 PRINT "            SPEAKER CONE PROCESSING INSTRUCTIONS":PRINT
380 PRINT "1. Determine the depth and width for your cone then run this program"
390 PRINT "   to calculate the circle and chord dimensions required for a flat"
400 PRINT "   paper stock pattern."
410 PRINT
420 PRINT "2. Using any convenient method, such as a compass or length of"
430 PRINT "   string, accurately draw the circle on your paper stock."
440 PRINT
450 PRINT "3. Then, using the chord length, draw a straight line anywhere on"
460 PRINT "   the circle such that both ends of the line are exactly on the"
470 PRINT "   circumference of the circle."
480 PRINT
490 PRINT "4. Now, draw a triangle using the center of the circle and the"
500 PRINT "   two points where the chord line touches the circle."
510 PRINT
520 PRINT "5. Step 4 shows the 'pie' section that needs to be cut out of the"
530 PRINT "   circle to make the cone.  NOTE, you need to leave an additional"
540 PRINT "   1/4 to 1/2 inch addition along one of the radii that you are"
550 PRINT "   cutting in order to have some extra stock for a glue joint overlap."
560 PRINT
570 INPUT "Press Enter to return",Q$:RUN
580 END
590 REM
600 REM
610 CLS:Z=0
620 COLOR 11:PRINT "      -------------------------- Cone Depth ---------------------------":COLOR 7
630 COLOR 2:PRINT "Cone  ";:COLOR 7
640   FOR H=H1-1.25 TO H1+1.25 STEP .25
650       IF H = H1 THEN COLOR 14 ELSE COLOR 11
660     PRINT USING "##.##";H;:PRINT " ";
670     COLOR 7
680   NEXT H:PRINT
690 COLOR 2:PRINT "Width";:COLOR 7:PRINT " ----------------------------------------------------------------- Pattern"
700 FOR W = W1-.75 TO W1+.75 STEP .25
710   FOR H = H1-1.25 TO H1+1.25 STEP .25
720     D = SQR((4*H*H)+(W*W))
730     A = 360*(D-W)/D*3.141/180
740     C = D * SIN(A/2)
750      IF W=W1 THEN COLOR 14 ELSE COLOR 2
760      IF Z=0 AND POS(0)=1 THEN PRINT USING "##.##";W; ELSE IF Z=1                        AND POS(0)=1 THEN PRINT "     ";
770    COLOR 7
780      IF W=W1 AND H=H1 THEN COLOR 12:D1=D
790      IF Z=0 THEN PRINT " ";:PRINT USING "##.##";D;
800    COLOR 7
810      IF W=W1-.75 AND H=H1+1.25 AND Z=0 THEN PRINT " <-Diam.";
820      IF H=H1 AND W=W1 THEN COLOR 12:C1=C
830      IF Z=1 THEN PRINT " ";:PRINT USING "##.##";C;
840    COLOR 7
850      IF W=W1-.75 AND H=H1+1.25 AND Z=1 THEN PRINT " <-Chord";
860      IF H=H1+1.25 AND Z=0 THEN H=H-2.75:Z=1:PRINT
870   NEXT H:Z=0:PRINT:IF CSRLIN <> 24 THEN PRINT
880 NEXT W:COLOR 15:PRINT "Press 1 to print these results (printer ready?) or 2 to return to main menu";
890 E$=INKEY$:IF E$="" THEN GOTO 890
900 IF ASC(E$)=49 THEN GOTO 930
910 IF ASC(E$)=50 THEN COLOR 7:RUN
920 GOTO 890
930 LPRINT "                   SPEAKER CONE PATTERN DESIGN PROGRAM"
940 LPRINT
950 LPRINT "      Request: cone depth - ";:LPRINT USING "##.##";H1;
960 LPRINT ",       cone width - ";:LPRINT USING "##.##";W1
970 LPRINT
980 LPRINT "      Result : pattern diameter - ";:LPRINT USING "##.##";D1;
990 LPRINT ", pattern chord - ";:LPRINT USING "##.##";C1
1000 LPRINT
1010 LPRINT "      -------------------------- Cone Depth ---------------------------"
1020 LPRINT "Cone  ";:COLOR 7
1030   FOR H=H1-1.25 TO H1+1.25 STEP .25
1040     LPRINT USING "##.##";H;:LPRINT " ";
1050   NEXT H:LPRINT
1060 LPRINT "Width";:LPRINT " ----------------------------------------------------------------- Pattern"
1070 FOR W = W1-.75 TO W1+.75 STEP .25
1080   FOR H = H1-1.25 TO H1+1.25 STEP .25
1090     D = SQR((4*H*H)+(W*W))
1100     A = 360*(D-W)/D*3.141/180
1110     C = D * SIN(A/2)
1120      IF Z=0 AND LPOS(0)=1 THEN LPRINT USING "##.##";W;                                  ELSE IF Z=1 AND LPOS(0)=1 THEN LPRINT "     ";
1130      IF Z=0 THEN LPRINT " ";:LPRINT USING "##.##";D;
1140      IF W=W1-.75 AND H=H1+1.25 AND Z=0 THEN LPRINT " <-Diam.";
1150      IF Z=1 THEN LPRINT " ";:LPRINT USING "##.##";C;
1160      IF W=W1-.75 AND H=H1+1.25 AND Z=1 THEN LPRINT " <-Chord";
1170      IF H=H1+1.25 AND Z=0 THEN H=H-2.75:Z=1:LPRINT
1180   NEXT H:Z=0:LPRINT:LPRINT
1190 NEXT W:LPRINT CHR$(12);:COLOR 7:RUN